sub:assertion {
  sub:get-all-space-membership-instances dct:description "This query returns all instances of Space membership instances." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get all Space membership instances" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix owl: <http://www.w3.org/2002/07/owl#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix gen: <https://w3id.org/kpxl/gen/terms/>
prefix schema: <http://schema.org/>

select (?__agent_multi_iri as ?agent) ?role ?roleName ?property ?inverse (?__space_multi_iri as ?space) where {
  values ?__space_multi_iri {}
  values ?__agent_multi_iri {}
  {
    {
      graph npa:graph {
        ?spaceRole_np npx:hasNanopubType gen:SpaceMemberRole .
        ?spaceRole_np npa:hasValidSignatureForPublicKeyHash ?spaceRole_pubkey .
        filter not exists { ?spaceRole_npx npx:invalidates ?spaceRole_np ; npa:hasValidSignatureForPublicKeyHash ?spaceRole_pubkey . }
        ?spaceRole_np np:hasAssertion ?spaceRole_a .
      }
      graph ?spaceRole_a {
        ?__space_multi_iri gen:hasRole ?role .
      }
    } union {
      bind(<https://w3id.org/np/RA_eEJjQbxzSqYSwPzfjzOZi5sMPpUmHskFNsgJYSws8I/adminRole> as ?role)
    }
  }
  graph ?role_a {
    ?role a gen:SpaceMemberRole .
    ?role rdfs:label ?roleLabel .
    ?role dct:title ?roleTitle .
    ?role schema:name ?roleName .
  }
  graph npa:graph {
    ?role_np npx:embeds ?role .
    ?role_np np:hasAssertion ?role_a .
  }
  {
    {
      graph ?role_a {
        ?role gen:hasRegularProperty ?reg .
      }
      graph ?link_a {
        ?__agent_multi_iri ?reg ?__space_multi_iri .
      }
      bind(?reg as ?property)
      bind(false as ?inverse)
    } union {
      graph ?role_a {
       ?role gen:hasInverseProperty ?inv .
      }
      graph ?link_a {
        ?__space_multi_iri ?inv ?__agent_multi_iri .
      }
      bind(?inv as ?property)
      bind(true as ?inverse)
    }
  }
  graph npa:graph {
    ?link_np np:hasAssertion ?link_a .
    ?link_np npa:hasValidSignatureForPublicKeyHash ?link_pubkey .
    filter not exists { ?link_npx npx:invalidates ?link_np ; npa:hasValidSignatureForPublicKeyHash ?link_pubkey . }
  }
}""" .
}