sub:assertion {
  sub:get-spaces-by-admin-orcid dct:description "Returns the list of spaces for which the given user (ORCID) is the admin." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "List spaces by admin ORCID" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix kpxl_terms: <https://w3id.org/kpxl/gen/terms/>

select ?space ?label ?np ?date where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    ?np dct:created ?date .
    ?np npx:introduces ?space .
    ?np npx:hasNanopubType kpxl_terms:Space .
    ?np rdfs:label ?label .
    ?np np:hasAssertion ?assertion .
    filter not exists {
      ?npx npx:introduces ?space .
      ?npx dct:created ?datex .
      filter(?datex > ?date)
    }
  }
  graph ?assertion {
    ?space kpxl_terms:hasAdmin ?_resource_iri .
  }
} order by ?label""" .
}