sub:assertion {
  sub:get-org-to-ns-associations dct:description "This query returns all organism-to-nucleotide-sequence associations." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get Organism to Nucleotide Sequence Associations" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/dc3636ccda207965f3ac58e3a54c80d1a9db39ba097848e5b41bf3fec7d66e44> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix biodiv: <https://w3id.org/kpxl/biodiv/terms/>
prefix biolink: <https://w3id.org/biolink/vocab/>
prefix nt: <https://w3id.org/np/o/ntemplate/>

select ?taxonName ?taxonName_label ?relation ?nucleotideSequence ?creator ?date ?np where {
  graph npa:graph {
    ?np npx:hasNanopubType biodiv:OrganismToNucleotideSequenceAssociation .
    ?np npa:hasValidSignatureForPublicKeyHash ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pubkey . }
    ?np dct:created ?date .
    ?np np:hasAssertion ?a .
    ?np np:hasPublicationInfo ?i .
    ?np npx:introduces ?association .
    optional { ?np npx:signedBy ?creator . }
  }
  graph ?a {
    ?association a biodiv:OrganismToNucleotideSequenceAssociation .
    ?association biolink:predicate ?relation .
    ?association biolink:subject ?organism .
    ?organism a ?taxonConcept .
    ?taxonConcept biodiv:hasTaxonName ?taxonName .
    ?association biolink:object ?nucleotideSequence .
  }
  graph ?i {
    optional { ?taxonName nt:hasLabelFromApi ?taxonName_label }
  }
}
order by desc(?date)""" .
}